100 REM GEORGE TREPAL COPYRIGHT 1985
110 REM 2650 ALTURAS RD
120 REM BARTOW, FL   33830
130 CLR:POKE53281,0:POKE53280,0:DIMTR(40):PRINT"[147][153]"
140 PRINTSPC(11)"DISK ERROR CHECKER"
150 PRINTSPC(8)"[158]NO KNOCK -- TRACKS 1-40"
160 PRINTSPC(12)"[159]BY GEORGE TREPAL"
170 PRINT"[153]CHECK <A>LL TRACKS OR <S>ELECTED TRACKS"
180 GETY$:IFY$<>"A"ANDY$<>"S"THEN180
190 IFY$="A"THENFT=1:LT=40:GOTO260
200 FT=-1:LT=50
210 INPUT"        FIRST TRACK TO CHECK";FT
220 IFFT<1ORFT>40THEN210
230 INPUT"        LAST TRACK TO CHECK";LT
240 IFLT<1ORLT>40THEN230
250 IFLT<FTTHEN210
260 PRINTSPC(5)"PRINT OUT ERRORS FOUND (Y/N)?"
270 GETY$:IFY$<>""THEN270
280 PF=0:GETY$:IFY$=""THEN280
290 IFY$="Y"THENPF=1
300 PRINT" INSERT DISK TO CHECK THEN PRESS RETURN"
310 PRINT SPC(2)"(FLASHING [150]RED[153] DRIVE LIGHT IS NORMAL)"
320 GETA$:IFA$<>CHR$(13)THEN320
330 OPEN15,8,15:PRINT#15,"I":CLOSE15
340 REM DEFINE # OF SECTORS ON TRACKS
350 FORJ=1TO17:TR(J)=20:NEXT:FORJ=18TO23:TR(J)=18:NEXT
360 FORJ=24TO30:TR(J)=17:NEXT:FORJ=31TO40:TR(J)=16:NEXT
370 FORT=FTTOLT:PRINT"[147]";:PRINTSPC(15)"TRACK ";T
380 PRINT"[153]   SECTOR    ERROR     EXPLANATION"
390 FORS=0TOTR(T)
400 PRINT"[153]SECTOR # ";S;:IFS<10THENPRINT" ";
410 OPEN15,8,15
420 PRINT#15,"M-W"CHR$(6)CHR$(0)CHR$(2)CHR$(T)CHR$(S)
430 PRINT#15,"M-W"CHR$(0)CHR$(0)CHR$(1)CHR$(128)
440 PRINT#15,"M-R"CHR$(0)CHR$(0)
450 GET#15,A$:A=ASC(A$+CHR$(0)):IFA>99THEN440
460 IFA=1THENPRINT" NO ERRORS":GOTO550
470 IFA=2THENB$="[158]BLOCK HEADER GONE"
480 IFA=3THENB$="[159]SYNC CHARACTER GONE"
490 IFA=4THENB$="[154]HEADER CHECKSUM BAD"
500 IFA=5THENB$="[156]READ CHECKSUM BAD"
510 IFA=6THENB$="BIT PATTERN ERROR"
520 IFA=9THENB$="HEADER CHECKSUM BAD"
530 IFA=11THENB$="[129]FORMAT ID MISMATCH"
540 PRINT" ";A+18;" ";B$
550 CLOSE15
560 IFPF=0ORA=1THEN590
570 OPEN4,4:CMD4:PRINT#4,"TRACK ";T;"   SECTOR";S;"  ERROR #";A+18;
580 PRINT#4,"    ";B$:CLOSE4
590 NEXT:NEXT
600 PRINTSPC(8)"PRESS RETURN TO CONTINUE[153]"
610 GETY$:IFY$<>CHR$(13)THEN610
620 GOTO130